Jak zjistit produktový klíč Windows 7, 8, 10 pomocí VBScriptu?

V mnoha situacích se může hodit najít produktový klíč Windows - a ne vždy ho máme po ruce. Zvlášť to pak platí, když dojde k poškození Windows a my je potřebujeme přeinstalovat. Právě tehdy se může hodit jednoduchý VBScript, který pomůže produktový klíč, ID a jméno extrahovat přímo ze systému bez použití nástrojů třetích stran.

 

Způsobů, jak vytáhnout produktový klíč z Windows je vícero. Zde přítomný VBScript nevyžaduje téměř nic, jen povolenou službu Windows Script Host. Defaultně bývá povolena, v některých systémech ji zakazují administrátoři, aby eliminovali oblíbený útočný vektor. Případně ji tedy povolíme postupem opačným návodu Jak zakázat Windows Script Host? 

Jak na použití VBScriptu:

• otevřeme Poznámkový blok; 
• vložíme do něj následující text: 

Option Explicit  
 
Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell") 
'Set registry key path 
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\" 
'Registry key value 
DigitalID = objshell.RegRead(Path & "DigitalProductId") 
Dim ProductName,ProductID,ProductKey,ProductData 
'Get ProductName, ProductID, ProductKey 
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName") 
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID") 
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey 
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then 
   Save ProductData  
End If 
 
 
 
'Convert binary to chars 
Function ConvertToKey(Key) 
    Const KeyOffset = 52 
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert 
    'Check if OS is Windows 8 
    isWin8 = (Key(66) \ 6) And 1 
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4) 
    i = 24 
    Maps = "BCDFGHJKMPQRTVWXY2346789" 
    Do 
           Current= 0 
        j = 14 
        Do 
           Current = Current* 256 
           Current = Key(j + KeyOffset) + Current 
           Key(j + KeyOffset) = (Current \ 24) 
           Current=Current Mod 24 
            j = j -1 
        Loop While j >= 0 
        i = i -1 
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput 
        Last = Current 
    Loop While i >= 0  
     
    If (isWin8 = 1) Then 
        keypart1 = Mid(KeyOutput, 2, Last) 
        insert = "N" 
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0) 
        If Last = 0 Then KeyOutput = insert & KeyOutput 
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5) 
    
     
End Function 
'Save data to a file 
Function Save(Data) 
    Dim fso, fName, txt,objshell,UserName 
    Set objshell = CreateObject("wscript.shell") 
    'Get current user name  
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
    'Create a text file on desktop  
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt" 
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set txt = fso.CreateTextFile(fName) 
    txt.Writeline Data 
    txt.Close 
End Function 

• uložíme soubor s požadovaným názvem ve formátu (tedy s koncovkou) VBS. Pokud by se ukládal jako TXT, je třeba název.vbs vložit do uvozovek); 
• spustíme VBS soubor;

• zobrazí se nám dialogové okno s produktovým jménem, ID a klíčem extrahovanými ze systému; 
• můžeme i rovnou uložit (do systémového umístění VBS souboru) v podobě textového souboru WindowsKeyInfo.txt odkliknutím Ano.

Zdroje: nononsence @ MyDigitalLife.net

 

Daniel Beránek, 01.04.2018 13:11

 

 

 

	Jak vypnout tučné písmo v rozhraní Google Chrome 124? Aktualizace Google Chrome 124 přináší mj. změny v uživatelském rozhraní. Konkrétně je to vizuální přestylování písma panelů a jiných prvků na tučnou variantu fontu. Ovšem na některých instalacích se změna potýká s...
	Jak aktivovat AI Notebook a Designer Image Editor v MS Edge? AI Notebook je novou funkcí Copilotu (patrně nejen v rozhraní MS Edge), která pozměňuje možnosti interakce s textovou generativní AI. Upouští od chatu ve prospěch vytvoření souvislého finálního textu. Designer Image Editor je od toho oddělený, samostatný...
	Jak aktivovat integrovaného Copilota v Evropě? Copilot je patrně první AI integrovaná přímo do operačního systému. Ovšem mimo vyhrazená území ho nevyužijete. A mezi ta území patří i starý kontinent. Tedy pokud nezkusíte Windows trošku potweakovat, aby z něj vypadl ten...
	Jak povolit rychlé zobrazení plochy kliknutím na hlavní panel: ve Windows 11? Rychlé zobrazení plochy je populární fičurkou všech operačních systémů. Kdykoliv se ztrácíte v záplavě oken, nebo potřebujete rychle spustit program či otevřít dokument, šikne se okny nezaplavená plocha, kterou většina uživatelů...